文章

DevOps持续集成与交付之Jenkins的使用及Pipeline语法讲解

DevOps持续集成与持续交付工具-Jenkins

Jenkins简介#

Jenkins是一个开源软件项目，是基于Java开发的一种持续集成工具，用于监控持续重复的工作，旨在提供一个开放易用的软件平台，使软件项目可以进行持续集成。

什么是持续集成（CI）？#

CI(Continuous integration，中文意思是持续集成)是一种软件开发实践。持续集成强调开发人员提交了新代码之后，立刻进行构建、编译、（单元）测试等这个过程，每次提交新代码都要进行此类重复操作，为了提高工作效率，避免重复工作及重复工作导致差别化问题。

什么是持续部署（CD）？#

CD(Continuous Delivery， 中文意思持续交付)是在持续集成的基础上，将集成后的代码部署到更贴近真实运行环境中，也就是说它是CI后紧跟的一个环节，当代码审核完毕打包成成品后，需要部署到真实的环境中去，这个过程也会根据代码的跟新持续的进行。

Jenkins安装#

采用docker形式安装，首先安装好docker服务，然后在安装机器中对要存储Jenkins数据的目录进行赋权：

  1. # groupadd jenkins -g 1000 && useradd jenkins -u 1000 -g jenkins
    # chown -R 1000:1000 /jenkins

uid 和 gid必须是1000，和Jenkins镜像中的对应

开始安装：

  1. # docker network create jenkins

    # docker run \
      --name jenkins-docker \
      --detach \
      --privileged \
      --network jenkins \
      --network-alias docker \
      --env DOCKER_TLS_CERTDIR=/certs \
      --volume /jenkins/certs:/certs/client \
      --volume /jenkins/data:/var/jenkins_home \
      --publish 8080:8080 \
      --publish 50000:50000 \
      jenkins/jenkins:latest

    ## 执行此命令获取初始密码
    # docker exec -it jenkins-docker cat /var/jenkins_home/secrets/initialAdminPassword

这个时候就可以通过 serverip:8080 来访问到Jenkins。

流水线（pipeline）概括#

想要更好的使用Jenkins，必须掌握其流水线（pipeline）的使用。

流水线概述#

  • 默认文件名为 Jenkinsfile
  • 采用 Groovy 语法
  • 其可以实现对代码的整合、编译、质量检测或部署等一系列操作，相当于我们说的“脚本”

流水线脚本的分类包括：脚本式、声明式#

脚本式语法结构

  1. node {
  2. stage('Example') {
  3. try {
  4. sh 'exit 1'
  5. }
  6. catch (exc) {
  7. echo 'Something failed, I should sound the klaxons!'
  8. throw
  9. }
  10. }
  11. }

声明式语法结构

  1. pipeline {
  2. agent any
  3. stages {
  4. stage('Example') {
  5. steps {
  6. echo 'Hello World'
  8. script {
  9. def browsers = ['chrome', 'firefox']
  10. for (int i = 0; i < browsers.size(); ++i) {
  11. echo "Testing the ${browsers[i]} browser"
  12. }
  13. }
  14. }
  15. }
  16. }
  17. }

我们应该用哪种方式来编写 Jenkinsfile？

推荐使用声明式语法结构来编写 Jenkinsfile，声明式语法结构的灵活性及可读性都要比脚本式语法结构要高，并且声明式结构中可以包含脚本式结构，可以说更强大一些，并且便于学习。

如何快速上手Jenkinsfile？#

  1. 多看Jenkinsfile示例文件，及官方的语法介绍：Pipeline Syntax (jenkins.io)，对语法有一个基础掌握。
  2. 学会使用脚本生成器

声明式常用语法介绍#

1、最外层的pipeline，整条流水线的开始，里边定义了流水线所有内容

  1. pipeline{
  3. }

2、agent，指定了流水线的执行节点，可以在pipeline的下行指定，也可以在stages的下行指定，agent有四个可选参数：

  1. pipeline{
  2. agent{
  3. node{
  4. label "container"
  5. customWorkspace '/some/other/path' //指定自定义的工作空间，其实就是指定自定义路径
  6. }
  7. }
  8. }

any：在任意节点执行pipeline

none：未定义，当顶层的agent none时，必须在每个stage下再单独定义agent

label：指定运行节点的label

node：自定义运行节点配置，例如指定label或customWorkspace，agent { node { label 'labelName' } } 和 agent { label 'labelName' }相同， 但 node支持其他选项 (比如customWorkspace).

3、stages（阶段）：包含一个或多个stage的序列，大部分执行操作都在这里，将每个离散部分串接起来，比如构建、测试和部署。

4、stage：包含在stages中，pipeline完成的所有实际工作都需要包含到stage中，每一个阶段都要有一个名字。

5、steps（步骤）：1个stage中，一般都要运行1个steps，里边可以直接运行linux命令。相当于3-5点是一个连续的、互相关联的，例如：

  1. pipeline {
  2. agent any
  3. stages {
  4. stage('Example') {
  5. agent { //选择执行节点，可以在此层级指定
  6. label 'nginx'
  7. }
  8. steps { //执行的步骤
  9. echo 'Hello World'
  10. }
  11. }
  12. }
  13. }

6、post：定义Pipeline或stage运行结束时的操作有以下多个参数可选：示例：

  1. pipeline {
  2. agent any
  3. stages {
  4. stage('Example') {
  5. steps {
  6. echo 'Hello World'
  7. }
  8. }
  9. }
  10. post {
  11. always {
  12. echo 'I will always say Hello again!'
  13. }
  14. }
  15. }

always：无论Pipeline运行的完成状态如何都会运行

changed：只有当前Pipeline或steps运行的状态与先前完成的Pipeline的状态不同时，才能运行

failure：仅当当前Pipeline或steps处于“失败”状态时才运行

success：仅当当前Pipeline或steps具有“成功”状态时才运行

unstable：只有当前Pipeline或steps具有“不稳定”状态才能运行

aborted：只有当前Pipeline或steps处于“中止”状态时才能运行

unsuccessful：只有当前Pipeline或steps运行为“未成功”状态才能运行

cleanup：无论Pipeline或steps运行后为什么状态，只要前边定义的状态都没匹配到，则运行

7、environment：环境变量，可以定义全局变量和特定的阶段变量，取决于其在流水线的位置，该指定支持一个特殊的方法credentials()，此方法可用于在Jenkins环境中通过标识符访问预定义的凭证，其有很多种类型：示例1：

  1. pipeline {
  2. agent any
  3. environment {
  4. CC = 'clang'
  5. }
  6. stages {
  7. stage('Example Secret Text') {
  8. environment {
  9. // 需要提前将凭据创建好Secret Text类型的凭据
  10. AN_ACCESS_KEY = credentials('my-predefined-secret-text')
  11. }
  12. steps {
  13. sh 'printenv'
  14. }
  15. }
  16. }
  17. }

示例2：

  1. pipeline {
  2. agent any
  3. stages {
  4. stage('Example Username/Password') {
  5. environment {
  6. // 提前创建好Username and Password类型的凭据
  7. SERVICE_CREDS = credentials('my-predefined-username-password')
  8. }
  9. steps {
  10. sh 'echo "Service user is $SERVICE_CREDS_USR"'
  11. sh 'echo "Service password is $SERVICE_CREDS_PSW"'
  12. }
  13. }
  14. stage('Example SSH Username with private key') {
  15. environment {
  16. // 提前创建好SSH Username with private key类型的凭据
  17. SSH_CREDS = credentials('my-predefined-ssh-creds')
  18. }
  19. steps {
  20. sh 'echo "SSH private key is located at $SSH_CREDS"'
  21. sh 'echo "SSH user is $SSH_CREDS_USR"'
  22. sh 'echo "SSH passphrase is $SSH_CREDS_PSW"'
  23. }
  24. }
  25. }
  26. }

Secret Text：指定的环境变量将设置为密文内容

Secret File：指定的环境变量将设置为临时创建的文件的位置

Username and password：指定的环境变量将设置为username:password，并将自动定义为两个环境变量：MYVARNAME_USR和MYVARNAME_PSW

SSH with Private Key：指定的环境变量将设置为临时创建的SSH密钥文件的位置，并且可以自动定义为两个环境变量：MYVARNAME_USR和MYVARNAME_PSW

8、options：此指令允许从Pipeline本身中配置一些特定的选项。Pipeline提供了许多这样的选项，例如buildDiscarder，也可以由插件提供，例如timestamps。分享一些参数：

buildDiscarder：保持构建的最大个数，示例：options { buildDiscarder(logRotator(numToKeepStr: '1')) }

checkoutToSubdirectory：在workspace的子目录中执行源代码自动管理切换，示例：options { checkoutToSubdirectory('foo') }

disableConcurrentBuilds：不允许同时执行管道。可用于防止同时访问共享资源等，示例：options { disableConcurrentBuilds() }

disableResume：如果控制器重新启动，则不允许恢复pipeline，示例： options { disableResume() }

newContainerPerStage：使用docker或dockerfile agent时。每个stage将在同一节点上的新容器实例中运行，而不是在同一容器实例中运行的所有stages。

overrideIndexTriggers：

retry：失败时，按指定次数重试整个管道，可以针对Pipeline或者Stage，示例：options { retry(3) }

skipStagesAfterUnstable：一旦构建状态变得不稳定，就跳过各个stages。示例： options { skipStagesAfterUnstable() }

timeout：设置管道运行的超时时间，此参数可以针对Pipeline或者Stage，例如：options { timeout(time: 1, unit: 'HOURS') }

timestamps： 所有控制台输出前加上线路发出的时间，此参数可以针对Pipeline或者Stage，示例：options { timestamps() }

  1. pipeline {
  2. agent any
  3. options {
  4. timeout(time: 1, unit: 'HOURS')
  5. timestamps()
  6. buildDiscarder(logRotator(numToKeepStr: '10'))
  7. }
  8. stages {
  9. stage('Example') {
  10. options {
  11. timeout(time: 1200, unit: 'SECONDS')
  12. }
  13. steps {
  14. echo 'Hello World'
  15. }
  16. }
  17. }
  18. }

9、parameters：为Pipeline运行前提供参数，有几种参数类型供选择：

  1. pipeline {
  2. agent any
  3. parameters {
  4. string(name: 'PERSON', defaultValue: 'Mr Jenkins', description: 'Who should I say hello to?')
  5. text(name: 'BIOGRAPHY', defaultValue: '', description: 'Enter some information about the person')
  6. booleanParam(name: 'TOGGLE', defaultValue: true, description: 'Toggle this value')
  7. choice(name: 'CHOICE', choices: ['One', 'Two', 'Three'], description: 'Pick something')
  8. password(name: 'PASSWORD', defaultValue: 'SECRET', description: 'Enter a password')
  9. }
  10. stages {
  11. stage('Example') {
  12. steps {
  13. echo "Hello ${params.PERSON}"
  14. echo "Biography: ${params.BIOGRAPHY}"
  15. echo "Toggle: ${params.TOGGLE}"
  16. echo "Choice: ${params.CHOICE}"
  17. echo "Password: ${params.PASSWORD}"
  18. }
  19. }
  20. }
  21. }

使用parameters参数有一个bug，首次构建时不会让你选择参数，第二次才可以选择。

string：字符串类型，示例：parameters { string(name: 'DEPLOY_ENV', defaultValue: 'staging', description: '') }

text：文本类型，可以包含多行，示例： parameters { text(name: 'DEPLOY_TEXT', defaultValue: 'One\nTwo\nThree\n', description: '') }

booleanParam：布尔类型，示例： parameters { booleanParam(name: 'DEBUG_BUILD', defaultValue: true, description: '') }

choice：选择类型，多个选项任选其一，示例： parameters { choice(name: 'CHOICES', choices: ['one', 'two', 'three'], description: '') }

password：密码类型，可以提前设置密码，示例： parameters { password(name: 'PASSWORD', defaultValue: 'SECRET', description: 'A secret password') }

10、triggers：触发器，定义了Pipeline自动化触发的方式，可触发的方式有：

  1. pipeline {
  2. agent any
  3. triggers {
  4. cron('H */4 * * 1-5')
  5. }
  6. stages {
  7. stage('Example') {
  8. steps {
  9. echo 'Hello World'
  10. }
  11. }
  12. }
  13. }

Jenkins cron syntaxJenkins cron语法遵循cron公共的语法（略有不同），每行由5个字段组成，由制表符或空格分隔。分钟小时日月周Minutes within the hour (0–59)The hour of the day (0–23)The day of the month (1–31)The month (1–12)The day of the week (0–7) where 0 and 7 are Sunday.要为一个字段指定多个值，可以使用以下运算符。按优先顺序展示：为了允许定期调度的任务在系统上产生均匀负载，应尽可能使用符号H（表示“哈希”），使其执行pipeline的时间分散，更好的利用资源。此外，支持使用 @yearly, @annually, @monthly, @weekly, @daily, @midnight, and @hourly 作为别名，他们都等同于使用哈希自动的进行均衡，例如@hourly 与H * * * 相同，表示1小时内任意时间执行即可。举一些cron例子： 指定所有的值M-N 指定值得范围M-N/X or */X 在指定的范围或者整个范围内，按照 X的值为间隔步长A,B,…,Z指定多个值cron：计划任务定期触发，示例： triggers { cron('H */4 * * 1-5') }pollSCM：与cron方式类似，但是必须发现有源码的变化，才会触发，示例： triggers { pollSCM('H */4 * * 1-5') }pollSCM触发器仅在Jenkins 2.22或更高版本中可用。upstream：接受以逗号分隔的作业字符串和阈值。当字符串中的任何作业以最小阈值结束时，将会触发，示例：triggers { upstream(upstreamProjects: 'job1,job2', threshold: hudson.model.Result.SUCCESS) }

每15分钟执行一次，可以是 at :07, :22, :37, :52：triggers{ cron('H/15 * * * *') }

在每小时的前30分钟，每10分钟执行一次：triggers{ cron('H(0-29)/10 * * * *') }

每周的周一到周五的，9点-16点之间的第45分钟每两个小时执行一次：triggers{ cron('45 9-16/2 * * 1-5') }

1-11月的每个1号和15号都要随机执行一次：triggers{ cron('H H 1,15 1-11 *') }

11、tools：工具，目前仅支持三种工具：maven、jdk和gradle。工具的名称必须在系统设置—>全局工具配置中定义。定义好后即可开始调用：

  1. pipeline {
  2. agent any
  3. tools {
  4. maven 'apache-maven-3.0.1'
  5. }
  6. stages {
  7. stage('Example') {
  8. steps {
  9. sh 'mvn --version'
  10. }
  11. }
  12. }
  13. }

第一次运行此工具时，如果没有会去下载，或者会根据你指定的获取方式去获取，比如直接从其他机器打包过来解压等方式。

12、input：stage 的 input 指令允许你使用 input step提示输入。 在应用了 options 后，进入 stage 的 agent 或评估 when 条件前， stage 将暂停。 如果 input 被批准, stage 将会继续。 作为 input 提交的任何参数都将在环境中用于其他 stage 使用。可选配置：示例：

  1. pipeline {
  2. agent any
  3. stages {
  4. stage('Example') {
  5. input {
  6. message "Should we continue?"
  7. ok "Yes, we should."
  8. submitter "alice,bob"
  9. parameters {
  10. string(name: 'PERSON', defaultValue: 'Mr Jenkins', description: 'Who should I say hello to?')
  11. }
  12. }
  13. steps {
  14. echo "Hello, ${PERSON}, nice to meet you."
  15. }
  16. }
  17. }
  18. }

message：必需的。 呈现给用户的信息。

id：可选的， 默认为 stage 名称。

ok：可选的，表单中 ok 按钮的描述文本。

submitter：可选的，以逗号分割的用户列表，只有列表用户才可以提交input内容。

parameters：可选参数列表，与前文介绍的相同。

13、when：逻辑判断，可以给定条件决定要不要执行此stage，when指令必须包含至少一个条件，如果when包含多个条件，则必须所有的条件都返回true，stage才会运行。内置条件有：示例：

  1. pipeline {
  2. agent any
  3. parameters {
  4. choice(name: 'BRANCH_NAME', choices: ['production', 'staging'], description: 'Pick something')
  5. string defaultValue: 'production', name: 'DEPLOY_TO', trim: true
  6. }
  7. stages {
  8. stage('Example Build') {
  9. when {
  10. expression { BRANCH_NAME ==~ /(production|staging)/ }
  11. }
  12. steps {
  13. echo "Start building ${BRANCH_NAME}"
  14. }
  15. }
  16. stage('Example Deploy') {
  17. when {
  18. anyOf {
  19. environment name: 'DEPLOY_TO', value: 'production'
  20. environment name: 'DEPLOY_TO', value: 'staging'
  21. }
  22. }
  23. steps {
  24. echo 'Deploying'
  25. }
  26. }
  27. }
  28. }

brance：分支匹配，当正在构建的分支与预设给定的分支匹配时，执行此stage，例如： when { branch 'master' }，此参数仅适用于多分支流水线。

environment：当指定的环境变量是给定的值时，执行此stage，例如：when { environment name: 'DEPLOY_TO', value: 'production' }

expression：当指定的Groovy表达式评估为true时，执行此stage，例如： when { expression { return params.DEBUG_BUILD } }

not：当嵌套条件是错误时，执行这个stage，必须包含一个条件，例如: when { not { branch 'master' } }

allOf：当所有的嵌套条件都正确时（当when中有多个条件时，默认就是此策略），执行这个此stage，必须包含至少一个条件，例如: when { allOf { branch 'master'; environment name: 'DEPLOY_TO', value: 'production' } }

anyOf：当至少有一个嵌套条件为真时，执行这个阶段,必须包含至少一个条件，例如: when { anyOf { branch 'master'; branch 'staging' } }

beforeAgent：默认为false，默认情况下，如果在stage中包含agent，则会在执行when之前会先执行agent，如果将beforeAgent设置为true，则表示先执行when条件，when条件判断为执行stage后，才执行agent。

14、Parallel：并行，声明式流水线的stage可以在他们内部声明多个嵌套stage, 它们将并行执行。注意，一个stage必须只有一个 steps 或 parallel ，嵌套的stage本身不能再进入 parallel 阶段，任何包含parallel的stage不能包含agent或tools，因为它们没有相关的step。另外，可以添加 failFast true 到包含 parallel的 stage 中，表示当其中一个进程失败时，所有的 parallel 阶段都将被终止。示例：

  1. pipeline {
  2. agent any
  3. options {
  4. parallelsAlwaysFailFast() //表示后续所有的parallel阶段中都设置为failFast true
  5. timestamps()
  6. }
  7. stages {
  8. stage('Build Stage') {
  9. steps {
  10. echo 'This stage is Build.'
  11. }
  12. }
  13. stage('Parallel Stage --> Deploy') {
  14. when {
  15. not{
  16. branch 'prod'
  17. }
  18. }
  19. parallel {
  20. stage('Branch dev') {
  21. agent {
  22. label "dev"
  23. }
  24. steps {
  25. echo "On Branch dev deploy"
  26. }
  27. }
  28. stage('Branch int') {
  29. agent {
  30. label "int"
  31. }
  32. steps {
  33. echo "On Branch int deploy"
  34. }
  35. }
  36. stage('Branch test') {
  37. agent {
  38. label "test"
  39. }
  40. stages {
  41. stage('Nested 1') {
  42. steps {
  43. echo "In stage Nested 1 within Branch test"
  44. }
  45. }
  46. stage('Nested 2') {
  47. steps {
  48. echo "In stage Nested 2 within Branch test"
  49. }
  50. }
  51. }
  52. }
  53. }
  54. }
  55. }
  56. }

此示例中：只要当branch不是prod时，则将同时在dev/int/test三个环境中deploy，test环境的deploy又分为两个stage，此两个stage并不是并行执行，而是串行执行。

15、script：脚本式语法，可以在声明式流水线中使用，包含在step里，调用script { }块，示例如下：

  1. pipeline {
  2. agent any
  3. stages {
  4. stage('Example') {
  5. steps {
  6. echo 'Hello World'
  8. script {
  9. def browsers = ['chrome', 'firefox']
  10. for (int i = 0; i < browsers.size(); ++i) {
  11. echo "Testing the ${browsers[i]} browser"
  12. }
  13. }
  14. }
  15. }
  16. }
  17. }

脚本式语法#

脚本式pipeline也是建立在底层流水线上的，与声明式不同的是, 脚本化流水线实际上是由 Groovy构建的通用 DSL， Groovy 语言提供的大部分功能都可以用于脚本化流水线。

脚本化流水线从 Jenkinsfile 的顶部开始向下串行执行, 就像 Groovy 或其他语言中的大多数传统脚本一样。 因此，提供流控制取决于 Groovy 表达式, 比如 if/else 条件, 例如:

  1. node {
  2. stage('Example') {
  3. if (env.BRANCH_NAME == 'master') {
  4. echo 'I only execute on the master branch'
  5. } else {
  6. echo 'I execute elsewhere'
  7. }
  8. }
  9. }

另一种方法是使用Groovy的异常处理支持来管理脚本化流水线流控制。当 步骤 失败 ，无论什么原因，它们都会抛出一个异常。处理错误的行为必须使用Groovy中的 try/catch/finally 块 , 例如:

  1. node {
  2. stage('Example') {
  3. try {
  4. sh 'exit 1'
  5. }
  6. catch (exc) {
  7. echo 'Something failed, I should sound the klaxons!'
  8. throw
  9. }
  10. }
  11. }

链接：https://www.cnblogs.com/v-fan/p/16547055.html

（版权归原作者所有，侵删）

声明： 本站所有文章，如无特殊说明或标注，均为本站原创发布。任何个人或组织，在未征得本站同意时，禁止复制、盗用、采集、发布本站内容到任何网站、书籍等各类媒体平台。如若本站内容侵犯了原著者的合法权益，可联系我们进行处理。
jenkins
持续集成

在Jenkins Pipeline中优雅地处理上游与下游Job结果

2024-12-5 17:00:34

持续集成

DevOps 工程师必备的 6 个 Linux 命令行工具

2024-12-9 12:17:10

0 条回复 A文章作者 M管理员
欢迎您，新朋友，感谢参与互动！
    暂无讨论，说说你的看法吧

请输入验证码

请输入图片中的验证码
点击发送按钮获取验证码

取消
×
×
￥undefined
请打开手机使用微信扫码支付
「」
×

....支付确认中....

「」
×
支付金额

￥

undefined
×
积分支付
您当前的积分为0

检测到您未绑定微信账户，请先绑定微信

立刻绑定
确定
×

打开微信扫一扫

扫码并「关注我们的公众号」安全快捷登录

×

下载海报：

个人中心
购物车
优惠劵
今日签到
私信列表
搜索
客服

  • 扫码打开当前页

返回顶部